FÓRMULAS DE EXCEL

Contar fechas por mes en Excel

Contar fechas por mes en Excel

Funciones utilizadas: SI.ERROR, K.ESIMO.MENOR, SI, FRECUENCIA, FILA, SUMAPRODUCTO, MES, CONTAR.SI.CONJUNTO, FIN.MES, FECHA

Suponiendo un rango aleatorio de fechas en A1:A20, podemos calcular la cantidad de fechas totales por mes y cantidad de fechas únicas por mes del siguiente modo:

Lo primero que haremos será nombrar al rango A1:A20 con el nombre «rango». Luego, utilizaremos el rango B1:B20 para crear una fórmula que nos liste los valores del rango original sin considerar repetidos. Para ello, nombramos a este rango «rango2» y aplicamos la siguiente fórmula matricial en todo el rango:

{=SI.ERROR(K.ESIMO.MENOR(SI(FRECUENCIA(rango;rango)>0;rango);FILA());"")}

Donde «rango» corresponde al rango A1:A20. Puedes obtener más información sobre éstas fórmulas que listan y/o ordenan rangos sin repetidos en los siguientes artículos:

Quitar duplicados en Excel con fórmula
Ordenar números sin repetir en Excel
Ordenar textos sin repetir en Excel

El paso siguiente será crear una tabla en D2:F14 con encabezados AÑO, MES y DÍA, y colocaremos el año correspondiente en la columna D, los números del 1 al 12 para cada mes en la columna E, y finalmente colocaremos un 1 en cada celda de la columna F. Esto se debe a que necesitaremos referenciar a una fecha dentro de cada mes para las fórmulas siguientes.

 

CALCULAR FECHAS TOTALES POR MES

Para calcular las fechas totales por mes, nos colocamos en la celda G3 y aplicamos la siguiente fórmula en todo el rango G3:G14:

=SUMAPRODUCTO(--(MES(rango)=E3))

Donde «rango» corresponde al rango A1:A20 y E3 corresponde al mes «1» dentro de la tabla de AÑO/MES/DÍA.

De esta forma obtenemos en el rango G3:G14, la cantidad de fechas totales distribuidas por mes para el rango original en A1:A20.

 

CALCULAR FECHAS ÚNICAS POR MES

Para calcular las fechas únicas por mes, nos colocamos en la celda H3 y aplicamos la siguiente fórmula en todo el rango H3:H14:

=CONTAR.SI.CONJUNTO(rango2;">="&FIN.MES(FECHA(D3;E3;F3);-1)+1;rango2;"<"&FIN.MES(FECHA(D3;E3;F3);0)+1)

Donde «rango2» corresponde al rango sin repetidos en B1:B20 y los valores en D3/E3/F3 corresponden a la fecha completa comprendida por el AÑO/MES/DÍA para cada fila.

De esta forma obtenemos en el rango H3:H14, la cantidad de fechas únicas distribuidas por mes para el rango original en A1:A20.

 

Finalmente, en el video realizamos una autosuma de todas las fechas de las columnas G y H para demostrar que en «fechas totales» se contabilizan todas las fechas del rango, y en «fechas únicas» sólo son contabilizadas las fechas únicas dentro del rango.

 

 

Te recomiendo ver el siguiente link con más videos de Fórmulas ingeniosas de Excel AQUÍ.

Salvo aclaración, todas las fórmulas y macros de este sitio están configuradas para aplicarse sobre la celda A1. Algunas fórmulas se encuentran encerradas entre llaves {} debido a que son fórmulas matriciales. Estas llaves no deben introducirse tecleándolas, sino que se generan automáticamente al aceptar la fórmula pulsando Control+Shift+Enter al mismo tiempo. Las fórmulas de este sitio son compatibles con versiones de Microsoft Excel® 2010 o superiores.