FÓRMULAS DE EXCEL

Hallar el carácter más repetido en una celda en Excel

Hallar el carácter más repetido en una celda en Excel

Funciones utilizadas: EXTRAE, MODA, COINCIDIR, FILA, INDIRECTO, LARGO

Suponiendo que disponemos de un rango de valores alfanuméricos con encabezado en el rango A1:A4 y que necesitamos hallar el carácter más repetido por cada celda del rango en el mismo rango de columna B, podemos utilizar alguna de las siguientes sintaxis para resolverlo, comenzando en B2 y arrastrando hacia abajo hasta B4:

HALLAR EL CARÁCTER MÁS REPETIDO EN UNA CELDA EN EXCEL (DESDE LA IZQUIERDA)

{=EXTRAE(A2;MODA(COINCIDIR(EXTRAE(A2;FILA(INDIRECTO("1:"&LARGO(A2)));1);EXTRAE(A2;FILA(INDIRECTO("1:"&LARGO(A2)));1);0));1)}

Donde «A2» corresponde a la primera celda con valores que necesitamos analizar.

HALLAR EL CARÁCTER MÁS REPETIDO EN UNA CELDA EN EXCEL (DESDE LA DERECHA)

{=EXTRAE(A2;LARGO(A2)-MODA(COINCIDIR(EXTRAE(A2;LARGO(A2)-FILA(INDIRECTO("1:"&LARGO(A2)))+1;1);EXTRAE(A2;LARGO(A2)-FILA(INDIRECTO("1:"&LARGO(A2)))+1;1);0))+1;1)}

Donde «A2» corresponde a la primera celda con valores que necesitamos analizar. Recordar de aceptar ambas fórmulas con la combinación CSE (Ctrl+Shift+Enter) por ser fórmulas matriciales.

Ambas fórmulas obtienen el mismo resultado si existe un sólo carácter repetido una máxima cantidad de veces. Sin embargo, cuando existen dos caracteres compitiendo por el carácter más repetido, cada fórmula devolverá el carácter que le corresponde. Es decir, si la celda a analizar contiene el valor «AAA111», la fórmula desde la izquierda devolverá «A» mientras que la fórmula desde la derecha devolverá «1».

De esta forma podemos resumir que si existe competencia por el carácter más repetido o si es indistinto uno u otro, podemos utilizar cualquiera de ambas fórmulas, caso contrario deberíamos utilizar la fórmula que necesitemos según su ubicación.

Ambas fórmulas utilizan la función MODA para obtener su resultado. Actualmente existen otras variantes de dicha función que son más eficientes, puedes conocerlas en el siguiente artículo: Funciones de tendencia central en Excel

De esta forma, logramos hallar rápidamente el carácter más repetido dentro de una celda, ya sea su contenido texto, números o una combinación de ambos.

Te recomiendo ver el siguiente link con más videos de Fórmulas ingeniosas de Excel AQUÍ.

Salvo aclaración, todas las fórmulas y macros de este sitio están configuradas para aplicarse sobre la celda A1. Algunas fórmulas se encuentran encerradas entre llaves {} debido a que son fórmulas matriciales. Estas llaves no deben introducirse tecleándolas, sino que se generan automáticamente al aceptar la fórmula pulsando Control+Shift+Enter al mismo tiempo. Las fórmulas de este sitio son compatibles con versiones de Microsoft Excel® 2010 o superiores.