FÓRMULAS DE EXCEL

Hallar un valor de referencia con la función BUSCARV según N valor repetido

Hallar un valor de referencia con la función BUSCARV según N valor repetido

Funciones utilizadas: CONTAR.SI, SI.ERROR, BUSCARV

 

Tal como se ejemplifica en el video. para poder hallar un valor de referencia con la función BUSCARV según N valor repetido y mediante fórmulas, podemos utilizar un método que consiste de tres pasos principales y que se basa en desarrollar una tabla donde especifique por columna cada valor buscado en función del número de repetición de cada valor del rango inicial.

El primer paso consiste en generar una columna auxiliar a la izquierda del rango de columna donde disponemos de los valores iniciales repetidos. Sobre esta columna de valores es donde vamos a buscar los valores repetidos y los listaremos en nuestra columna auxiliar agregándoles el número de repetición a medida que bajamos en el rango. Por ej. «Mariano Godoy1», luego «Mariano Godoy2» y así sucesivamente. La fórmula utilizada en A2 que corresponde a la primer celda paralela sin encabezado de nuestra columna auxiliar es la siguiente:

=B2&CONTAR.SI($B$2:B2;B2)

Donde B2 es igual a la celda que contiene el primer valor del rango inicial sin considerar encabezados. Debemos arrastrar ésta fórmula hasta el último valor del rango inicial.

El segundo paso consiste en aplicar una fórmula sobre la tabla final que liste todos los valores del rango inicial sin repeticiones, para ello recurrimos a la fórmula explicada en un artículo anterior que puedes visitar aquí: Quitar duplicados en Excel con fórmula

{=INDICE(lista;K.ESIMO.MENOR(SI(COINCIDIR(lista;lista;0)=FILA(INDIRECTO("1:"&CONTARA(lista)));COINCIDIR(lista;lista;0);"");FILA()-1))}

Esta fórmula se aplica sobre un rango llamado «lista» que es el nombre que debemos asignarle a nuestro rango inicial y debemos arrastrar hacia abajo en nuestra tabla hasta hallar el primer resultado de error.

Finalmente una vez obtenidos todos los valores individualizados sin repeticiones, debemos generar una fórmula por fila que devuelva el valor buscado en función del número de repetición que necesitemos. La fórmula para la primer repetición que utilizamos es la siguiente:

=SI.ERROR(BUSCARV(A2&1;Hoja1!$A:$C;3;0);"")

Donde A2 corresponde al primer valor de nuestra lista sin repetición y del cual combinaremos el argumento «1» para que encuentre en nuestra columna auxiliar la primer repetición de dicho valor y nos devuelva un valor objetivo en función de la columna requerida. Luego y por cada número de repetición iremos alterando la fórmula por fila con los argumentos «2», «3», etc hasta que consideremos los últimos valores repetidos.

De esta forma logramos generar una tabla que desglosa por columna un valor objetivo en función de cada repetición de los valores de un rango de datos, en otras palabras, nos permite hallar un valor de referencia mediante fórmulas con la función BUSCARV según «N» valor repetido.

 

Te recomiendo ver el siguiente link con más videos de Fórmulas ingeniosas de Excel AQUÍ.

Salvo aclaración, todas las fórmulas y macros de este sitio están configuradas para aplicarse sobre la celda A1. Algunas fórmulas se encuentran encerradas entre llaves {} debido a que son fórmulas matriciales. Estas llaves no deben introducirse tecleándolas, sino que se generan automáticamente al aceptar la fórmula pulsando Control+Shift+Enter al mismo tiempo. Las fórmulas de este sitio son compatibles con versiones de Microsoft Excel® 2010 o superiores.