FÓRMULAS DE EXCEL

Separar texto y números de una celda en Excel

Separar texto y números de una celda en Excel

Funciones utilizadas: MIN, HALLAR, IZQUIERDA, DERECHA, LARGO

Suponiendo que disponemos de un rango de valores con texto y números en A2:A21 y que quisiéramos obtener por separado el texto y los números de cada celda del rango, podemos utilizar un método que consiste en el uso de una columna auxiliar (columna C) y las dos columnas para texto y números (columnas D y E respectivamente). Es importante notar que éste método funciona únicamente si la parte de texto se encuentra a la izquierda de la parte de valores numéricos dentro de cada celda del rango.

Lo primero que haremos será crear un valor divisor que representa el número de carácter a partir del cual la celda pasa de texto a valor numérico. Por ej. si la celda contiene el valor «Rubén344», el valor divisor será «6», dado que el sexto carácter de la celda es el primer valor numérico dentro de la misma. De esta forma, aplicamos la siguiente sintaxis en la celda C2 y arrastramos hacia abajo la fórmula:

=MIN(HALLAR({0;1;2;3;4;5;6;7;8;9};A2&"0123456789"))

Donde A2 corresponde a la primera celda objetivo del rango a separar. Al combinar las funciones MIN y HALLAR logramos que la fórmula nos devuelva el número de carácter en el que se encuentra el primer valor numérico hallado de izquierda a derecha. Para ello utilizamos una matriz de búsqueda con todos los números posibles y en el argumento dentro_del_texto de la función HALLAR, concatenamos cada número posible 0-9 con el texto original en la celda objetivo (A2) para evitar errores en la fórmula si no se encuentra un número posible.

Para obtener sólo la parte de texto de la celda objetivo utilizamos la siguiente sintaxis en la celda D2 y arrastramos hacia abajo la función:

=IZQUIERDA(A2;C2-1)

Donde A2 corresponde a la primera celda objetivo del rango a separar, y C2 corresponde al valor divisor para dicha celda definido con la fórmula anterior. De esta forma, definimos como número de caracteres a extraer el valor del divisor menos 1, logrando omitir la parte que contiene valores numéricos.

Finalmente, para obtener sólo la parte de valores numéricos de la celda objetivo utilizamos la siguiente sintaxis en la celda E2 y arrastramos hacia abajo la fórmula:

=DERECHA(A2;LARGO(A2)-C2+1)

Donde A2 corresponde a la primera celda objetivo del rango a separar, y C2 corresponde al valor divisor para dicha celda definido con la primera fórmula del artículo. Combinamos las funciones DERECHA y LARGO para obtener sólo la parte numérica de la celda. Esto se logra gracias a que definimos el argumento que representa el número de caracteres de la función DERECHA con la diferencia entre el total de caracteres de la celda objetivo (función LARGO) y el valor del divisor más 1.

De esta forma logramos obtener mediante el cálculo de un divisor texto/número, los valores por separado de texto y valores numéricos de una celda o rango específico.

 

Te recomiendo ver el siguiente link con más videos de Fórmulas ingeniosas de Excel AQUÍ.

Salvo aclaración, todas las fórmulas y macros de este sitio están configuradas para aplicarse sobre la celda A1. Algunas fórmulas se encuentran encerradas entre llaves {} debido a que son fórmulas matriciales. Estas llaves no deben introducirse tecleándolas, sino que se generan automáticamente al aceptar la fórmula pulsando Control+Shift+Enter al mismo tiempo. Las fórmulas de este sitio son compatibles con versiones de Microsoft Excel® 2010 o superiores.