FÓRMULAS DE EXCEL

Sumar celdas que contienen A o B en Excel

Sumar celdas que contienen A o B en Excel

Funciones utilizadas: SUMAPRODUCTO, ESNUMERO, HALLAR, SUMA, SI.ERROR, SI, ENCONTRAR

Suponiendo que necesitamos sumar los valores numéricos del rango B2:B10 en función de un rango de valores de texto paralelo en A2:A10, donde la condición de suma implica contener alguno de dos textos específicos «azul» o «rojo», podemos aplicar tres métodos similares para lograrlo:

MÉTODO SUMAPRODUCTO

Este método combina la función SUMAPRODUCTO con las funciones HALLAR y ESNUMERO. La sintaxis que debemos aplicar en la celda de resultado es la siguiente:

=SUMAPRODUCTO(--((ESNUMERO(HALLAR("azul";A2:A10))+ESNUMERO(HALLAR("rojo";A2:A10)))>0);B2:B10)

Donde A2:A10 corresponde al rango de valores de texto a analizar y B2:B10 corresponde al rango de valores numéricos a ser sumados.

La combinación de las funciones HALLAR y ESNUMERO devuelven por cada matriz VERDADERO o FALSO para cada celda del rango. Al sumar dos matrices obtenemos una nueva matriz de o y 1 donde debemos contar una sola vez cada valor mayor a 0, con lo cual aplicamos el filtro «>0» para reconvertir a VERDADERO o FALSO y luego sumar con la conversión del doble operador «–«.

MÉTODO SUMA + SI.ERROR

Este método combina la función SUMA con las funciones SI.ERROR y HALLAR. La sintaxis que debemos aplicar en la celda de resultado es la siguiente:

{=SUMA(((SI.ERROR(((HALLAR("azul";A2:A10;1)>0)*1);0)+SI.ERROR(((HALLAR("rojo";A2:A10;1)>0)*1);0)>0)*1)*B2:B10)}

Donde A2:A10 corresponde al rango de valores de texto a analizar y B2:B10 corresponde al rango de valores numéricos a ser sumados. Recordar de aceptar con CTRL+SHIFT+ENTER por ser una función matricial.

Este método convierte a 0 cada valor de error que devuelve la función HALLAR para no ser sumado luego al aplicar la función SUMA. Finalmente se multiplica cada valor del rango objetivo por 1 en aquellos casos en que el valor debe ser sumado gracias al cálculo anterior.


MÉTODO SUMA + ESNUMERO

Este método combina la función SUMA con las funciones SI, ESNUMERO Y HALLAR. La sintaxis que debemos aplicar en la celda de resultado es la siguiente:

{=SUMA(SI(ESNUMERO(HALLAR("azul";A2:A10))+ESNUMERO(HALLAR("rojo";A2:A10))>=1;1;0)*B2:B10)}

Donde A2:A10 corresponde al rango de valores de texto a analizar y B2:B10 corresponde al rango de valores numéricos a ser sumados. Recordar de aceptar con CTRL+SHIFT+ENTER por ser una función matricial.

Este método aplica la función SI para convertir a 1 si el resultado de hallar alguno de ambos textos es positivo. Finalmente se multiplica cada valor del rango objetivo por 1 en aquellos casos en que el valor debe ser sumado gracias al cálculo anterior.

 

De esta forma, logramos obtener de forma rápida y efectiva la sumatoria de un rango para aquellos valores que contienen A o B en un rango paralelo. Si necesitamos distinguir entre mayúsculas y minúsculas podemos reemplazar cada instancia de la función HALLAR por la función ENCONTRAR dentro de cada sintaxis.

 

Te recomiendo ver el siguiente link con más videos de Fórmulas ingeniosas de Excel AQUÍ.

Salvo aclaración, todas las fórmulas y macros de este sitio están configuradas para aplicarse sobre la celda A1. Algunas fórmulas se encuentran encerradas entre llaves {} debido a que son fórmulas matriciales. Estas llaves no deben introducirse tecleándolas, sino que se generan automáticamente al aceptar la fórmula pulsando Control+Shift+Enter al mismo tiempo. Las fórmulas de este sitio son compatibles con versiones de Microsoft Excel® 2010 o superiores.