Consolidar datos en una sola hoja en Excel (macro)

Consolidar datos en una sola hoja en Excel (macro)

¿Cómo podemos consolidar distintos datos en una sola hoja mediante el uso de macros en Excel?

La siguiente macro nos permite generar un reporte que suma los valores de una columna predefinida de distintas hojas en una hoja nueva mediante macros de forma rápida y fácil en Excel.

La instrucción a copiar dentro de un nuevo módulo de vba es la siguiente:

CONSOLIDAR DATOS EN UNA SOLA HOJA EN EXCEL

Sub ConsolidarImportes()
    Dim hoja As Worksheet
    Dim hojaReporte As Worksheet
    Dim filaDestino As Long
    Dim letraColumna As String
    Dim totalHoja As Double
    
    letraColumna = "B"

    On Error Resume Next
    Set hojaReporte = ThisWorkbook.Sheets("Reporte General")
    If hojaReporte Is Nothing Then
        Set hojaReporte = ThisWorkbook.Sheets.Add
        hojaReporte.Name = "Reporte General"
    Else
        hojaReporte.Cells.Clear
    End If
    On Error GoTo 0

    hojaReporte.Range("A1").Value = "Mes"
    hojaReporte.Range("B1").Value = "Importe Total"
    hojaReporte.Range("A1:B1").Font.Bold = True
    filaDestino = 2

    For Each hoja In ThisWorkbook.Worksheets
        If hoja.Name <> "Reporte General" Then
            
            totalHoja = Application.WorksheetFunction.Sum(hoja.Columns(letraColumna))
            
            hojaReporte.Cells(filaDestino, 1).Value = hoja.Name
            hojaReporte.Cells(filaDestino, 2).Value = totalHoja
            
            filaDestino = filaDestino + 1
        End If
    Next hoja

    hojaReporte.Columns("B").NumberFormat = "$ #,##0.00"
    hojaReporte.Columns("A:B").AutoFit
    MsgBox "¡Reporte completado!", vbInformation
End Sub

Notar que nombramos a la macro «ConsolidarImportes» y que debemos definir la letra de la columna de la cual debemos sumar sus valores en la siguiente línea de código «letraColumna = «B»».

De esta forma logramos consolidar datos en una sola hoja de forma rápida y fácil mediante macros en Excel.

Te recomiendo ver el siguiente link con más videos de Macros útiles de Excel AQUÍ.

¿No sabés como instalar esta macro? ¡No te preocupes!  Aquí está la solución:

Salvo aclaración, todas las fórmulas y macros de este sitio están configuradas para aplicarse sobre la celda A1. Algunas fórmulas se encuentran encerradas entre llaves {} debido a que son fórmulas matriciales. Estas llaves no deben introducirse tecleándolas, sino que se generan automáticamente al aceptar la fórmula pulsando Control+Shift+Enter al mismo tiempo. Las fórmulas de este sitio son compatibles con versiones de Microsoft Excel® 2010 o superiores.