TUTORIALES DE EXCEL

Cómo usar INDICE y COINCIDIR en Excel

Cómo usar INDICE y COINCIDIR en Excel

¿Cómo usar INDICE y COINCIDIR en Excel?

En el video tutorial ejemplificamos cuatro de los usos más populares de la combinación entre la función INDICE y la función COINCIDIR en Excel. 

La función INDICE en Excel nos permite obtener el valor de una celda dentro de una matriz especificada por el número de fila y columna, mientras que la función COINCIDIR en Excel nos permite localizar un valor dentro de un rango de celdas devolviendo su posición dentro del rango. De esta forma al combinar ambas funciones logramos obtener un valor producto de la definición de coordenadas de fila y columna para una matriz dada.

La combinación de las funciones INDICE y COINCIDIR suele ser a menudo comparada con la función BUSCARV debido a la similitud de resultados que se pueden obtener al utilizar ambos métodos en una búsqueda particular. Puedes obtener mayor información de la función BUSCARV en el siguiente artículo: Función BUSCARV en Excel

No obstante, la función BUSCARV tiene una limitante de posicionamiento, debido a que en la matriz de búsqueda, la columna del valor buscado debe encontrarse en la misma columna o a la izquierda del valor a devolver. Aún asi, existe una forma de eludir dicha restricción que presentamos en el siguiente artículo: Función BUSCARV INVERSO

Presentamos a continuación las distintas opciones de sintaxis que suelen utilizarse con la fórmula INDICE+COINCIDIR:


ESTÁNDAR

Suponiendo un rango de datos con encabezado en A1:E11, y que necesitamos hallar los datos de la columna B de un registro (por fila) en base al valor en I2 que se encuentra en alguna celda de la columna A, podemos utilizar la siguiente sintaxis:

=INDICE(B2:B11;COINCIDIR(I2;A2:A11;0))

Donde B2:B11 corresponde al rango de posibles resultados, I2 corresponde al valor a buscar en la columna A, y A2:A11 es el rango de valores donde es buscado el valor de I2. El argumento «0» implica que la búsqueda es exacta, es decir que devolverá un valor correcto si encuentra el valor de I2 en la columna A.

 

APROXIMADA

La búsqueda aproximada es similar a la estándar pero considera los valores aproximados al valor de búsqueda. Para ello debemos modificar el argumento «0» de búsqueda exacta por «1» si queremos que también nos devuelva valores menores o iguales al valor encontrado, o «-1» si queremos que también nos devuelva valores mayores o iguales al valor encontrado.

La sintaxis de cada fórmula queda definida de la siguiente forma:

Búsquedas aproximadas menores o iguales

=INDICE(B2:B11;COINCIDIR(I3;A2:A11;1))

Búsquedas aproximadas mayores o iguales

=INDICE(B2:B11;COINCIDIR(I3;A2:A11;-1))

 

EXACTA

La búsqueda exacta no se refiere a la búsqueda estándar, sino a una búsqueda que considera mayúsculas y minúsculas al buscar un valor dentro de un rango. En el video demostramos que tanto la función BUSCARV como la combinación INDICE+COINCIDIR no consideran letras mayúsculas y minúsculas para tratar a cada valor de una celda, con lo cual si en nuestro rango de datos necesitamos encontrar por ejemplo el nombre «LAURA» y en nuestro rango de datos tenemos «Laura» en A1 y «LAURA» en A2, ambas funciones considerarán al valor en A1 debido a que no distinguen el formato de dichas letras. Para los casos en que necesitemos una búsqueda exacta con distinción de mayúsculas y minúsculas debemos añadir la función IGUAL a la combinación INDICE+COINCIDIR y convertir la fórmula a una fórmula matricial.

Suponiendo un rango de datos con encabezado en A1:D4, que necesitamos devolver el valor en la columna B y que el valor de búsqueda en H2 debe buscarse en la columna A, la sintaxis que utilizaremos es la siguiente:

{=INDICE(B2:B4;COINCIDIR(VERDADERO;IGUAL(H2;A2:A4);0))}

Donde B2:B4 es el rango de datos de posibles resultados, H2 es el valor buscado, y A2:A4 es el rango de búsqueda para el valor en H2. Debemos aceptar la fórmula con CTRL+SHIFT+ENTER por ser matricial.

La inclusión de la función IGUAL nos permite buscar un «VERDADERO» dentro de una búsqueda de VERDADEROS y FALSOS que devuelve la matriz de búsqueda, donde el valor VERDADERO encontrado corresponde al valor exacto de búsqueda en H2. Es importante remarcar que la función COINCIDIR siempre devolverá el primer dato exacto encontrado, con lo cual si la matriz de búsqueda encuentra más de un VERDADERO debido a que por ejemplo existen dos registros iguales, devolverá el primer registro encontrado (superior en un rango de columna).

 

DOBLE ENTRADA

La búsqueda de doble entrada suele utilizarse cuando disponemos de un rango de datos que posee dos encabezados que definen un resultado en común. Al igual que en los casos anteriores, podemos utilizarla en casos de una búsqueda estándar exacta y una búsqueda aproximada pero sólo «menor o igual que».

Suponiendo un rango de datos con encabezado doble (fila y columna) en A1:E5, utilizamos la celda I2 para definir un rango de fila (A2:A5), y la celda I3 para definir un rango de columna (B1:E1), y configuramos la siguiente sintaxis para obtener el registro EXACTO que cruze ambos ejes de coordenadas:

=INDICE(B2:E5;COINCIDIR(I2;A2:A5;0);COINCIDIR(I3;B1:E1;0))

Donde B2:E5 corresponde al rango total de datos sin los encabezados, I2 corresponde al valor buscado dentro del eje de fila, A2:A5 corresponde al encabezado que contiene los valores buscados de fila, I3 corresponde al valor buscado dentro del eje de columna, B1:E1 corresponde al encabezado que contiene los valores buscados de columna.

La función INDICE nos permite obtener el valor dentro de la matriz, y la numeración de fila y columna queda definido por las dos funciones COINCIDIR que nos indican los valores de los ejes que debemos encontrar para obtener el valor que cruza ambos ejes. Utilizamos el argumento «0» dentro de cada función COINCIDIR para que únicamente sean considerados los valores de ejes EXACTOS que definimos en I2 e I3. Si los valores en dichas celdas no son encontrados dentro de los rangos de ejes de la matriz, la fórmula devolverá error.

Si necesitamos que la fórmula nos devuelva el valor que más se aproxime a los dos valores de ejes definidos en I2 e I3, debemos modificar el argumento «0» por «1» dentro de la sintaxis anterior. De esta forma, si por ejemplo el valor en I2 no es encontrado en el rango A2:A5, la funcíón COINCIDIR considerará el valor menor o igual que sea más cercano a dicho valor en I2 para definir la columna de dicho eje. Del mismo modo sucederá para el valor I3 dentro del rango B1:E1. La sintaxis quedaría definida del siguiente modo:

=INDICE(B2:E5;COINCIDIR(I2;A2:A5;1);COINCIDIR(I3;B1:E1;1))

 

 

 

Te recomiendo ver el siguiente link con más videos de Tutoriales esenciales de Excel AQUÍ.

Salvo aclaración, todas las fórmulas y macros de este sitio están configuradas para aplicarse sobre la celda A1. Algunas fórmulas se encuentran encerradas entre llaves {} debido a que son fórmulas matriciales. Estas llaves no deben introducirse tecleándolas, sino que se generan automáticamente al aceptar la fórmula pulsando Control+Shift+Enter al mismo tiempo. Las fórmulas de este sitio son compatibles con versiones de Microsoft Excel® 2010 o superiores.